Dynamic Allocation of PS Dataset Using a COBOL program.

 Hi Mainframe,

In most of Mainframe Shops, we use JCL for Allocation of PS Dataset. But Many a times a requirement comes where we need to allocates a PS dataset dynamically within a COBOL program which catalog the Files and once catalog the Allocated PS Dataset can be used to perform various File I/O operations such as Open, Read, Write and Close file.

In order to Achieve these IBM has provide many Utility as such Sub program can be called in the COBOL main program as a Static call with the Appropriate TSO command to Allocate a new File Dynamically. 

Syntax for PS Data Set Allocations is: DSN(&SYSUID..MVS.TEST.FILE01) NEW TRACKS SPACE(100,100) UNIT(SYSDA) CATALOG

The file name is Specified in the DSN and any number of Files can be Allocated using IBM Supplied Utility.

The most come IBM Utility Used is: 'PUTENV'

This Utility or Subprogram is called STATICALLY with the Above mention DSN details....

       ID DIVISION.
       PROGRAM-ID.   GETENVX.
       AUTHOR.       Sandeep R Prajapati.
       DATE-WRITTEN.
       DATE-COMPILED.
       ENVIRONMENT DIVISION.
       INPUT-OUTPUT SECTION.
       FILE-CONTROL.
           SELECT TEST-FILE ASSIGN TO DD1.
       DATA DIVISION.
       FILE SECTION.
       FD  TEST-FILE
           LABEL RECORDS ARE STANDARD
           BLOCK CONTAINS 0 RECORDS.
       01  TEST-REC           PIC X(80).
           EJECT
       WORKING-STORAGE SECTION.

       01  OUTPUT-REC.
           05  REC-NUM         PIC 9(10).
           05  FILLER          PIC X(70)        VALUE SPACES.

       01 WS-WORK-DSN PIC X(55) VALUE 'TTT.TTT.TTT'.
       01 WS-DYNAMIC-OPEN-AREA.
           05 FILE-NAME.
               10 FILLER PIC X(8)  VALUE 'DD1=DSN('.
               10 DSNAME PIC X(55) VALUE SPACE.
               10 FILLER PIC X(50) VALUE
                   ' NEW TRACKS SPACE(100,100) UNIT(SYSDA) CATALOG '.
               10 FILLER PIC X(01) VALUE X'00'.
           05 FILE-PTR POINTER.
           05 RC PIC S9(9) BINARY VALUE ZERO.
       01  FNAMES.
           05  FNAME-01             PIC X(55)    VALUE
               'Z80076.PS.TESTFILE.OUT01'.
           05  FNAME-02             PIC X(55)    VALUE
               'Z80076.PS.TESTFILE.OUT02'.
           05  FNAME-03             PIC X(55)    VALUE
               'Z80076.PS.TESTFILE.OUT03'.
           05  FNAME-04             PIC X(55)    VALUE
               'Z80076.PS.TESTFILE.OUT04'.
       01  FNAME-TABLE REDEFINES FNAMES.
           05  FNAME                PIC X(55)    OCCURS 4 TIMES.
       01  SUB                      PIC S9(9)    COMP-3.
       LINKAGE SECTION.
           EJECT
       PROCEDURE DIVISION.

           PERFORM
           VARYING SUB FROM 1 BY 1 UNTIL SUB > 4
               MOVE SPACE TO DSNAME
               MOVE FNAME(SUB)              TO WS-WORK-DSN
               STRING WS-WORK-DSN DELIMITED BY SPACE
                   ')' DELIMITED BY SIZE
                   INTO DSNAME
               DISPLAY 'FILE-NAME = ' FILE-NAME
               SET FILE-PTR TO ADDRESS OF FILE-NAME
               CALL 'PUTENV' USING BY VALUE FILE-PTR RETURNING RC
               IF RC NOT = 0
               THEN
                   MOVE RC     TO RETURN-CODE
                   GOBACK
               END-IF
               OPEN OUTPUT TEST-FILE
               PERFORM
               10 TIMES
                   ADD 1 TO REC-NUM
                   WRITE TEST-REC FROM OUTPUT-REC
               END-PERFORM
               CLOSE TEST-FILE
           END-PERFORM.

           MOVE 0           TO RETURN-CODE.

           GOBACK.




Thanks,

Sandeep R Prajapati

Technology Analyst @ Infosys.

Comments

Post a Comment

Popular posts from this blog

Sort JCL in Descending Order and Format the output

Image
JCL sort is IBM utility used for sorting input data source such as PS, VSAM or SMS files. In this example I will demonstrate on How to Sort the Sequential Data set in Descending order and in the last, format the record in such a way that we will only get the selected column values in the output file JCL: This JCL executes SORT program in 2 steps Step01 - sorts the input file in Descending Order Step02 - copy the input file in output while in specified Format only. //* THIS JCL SORTS THE OUTPUT FILE IN DESCENDING ORDER       //* AND FORMATS THE OUTFILE                                  //STEP01   EXEC PGM=SORT                                     //SYSOUT   DD SYSOUT=*                                       //SORTIN   DD DSN=G101105.CLAIM.EXTRACT1,DISP=SHR            //SORTOUT  DD DSN=G101105.CLAIM.SORTED,                      //         DISP=(NEW,CATLG),UNIT=SYSDA,                      //         SPACE=(CYL,(100,100),RLSE),                       //         DCB=(LRECL=135,RECFM=FB,BLKSIZE=
Read more

COBOL INSPECT Function

Image
In the real world scenario many a times you required to find the length of string value to do a concatenation or string parse but more commonly is used in the VARCHAR column data type of DB2 table. Hence it becomes important for any application to be aware of the COBOL function available to calculate the length of the input string. one of the very common methods used in COBOL for finding the length of the string is to use a INSPECT function. the INSPECT function majorly are of two times. in this blog I will shows you the following 2 types of INSPECT TALLYING function which help to get the length of string, very much need in teal world scenarios. Basic syntax: Below is the example of the COBOL code which receives data from JCL using instream and PARM parameter instream data received by the COBOL program by issuing a ACCEPT statement whereas, the PARM parameter is received by the COBOL program by using LINKAGE SECTION and by mentioning PROCEDURE USING linkage section structure. you can c
Read more